как да генерирам графика на равнинен набор на Кантор в mathematica

Ето един наивен и вероятно не много оптимизиран начин за възпроизвеждане на графиките за строителство на троен набор на Кантор:

cantorRule = Line[{{a_, n_}, {b_, n_}}] :> 
  With[{d = b - a, np = n - .1}, 
       {Line[{{a, np}, {a + d/3, np}}], Line[{{b - d/3, np}, {b, np}}]}]

Graphics[{CapForm["Butt"], Thickness[.05], 
  Flatten@NestList[#/.cantorRule&, Line[{{0., 0}, {1., 0}}], 6]}]

За да направим Cantor dust, използвайки същите правила за заместване, ние вземаме резултата на определено ниво , напр. 4:

dust4=Flatten@Nest[#/.cantorRule&,Line[{{0.,0},{1.,0}}],4]/.Line[{{a_,_},{b_,_}}]:>{a,b}

и вземете кортежи от него

dust4 = Transpose /@ Tuples[dust4, 2];

След това просто начертаваме правоъгълниците

Graphics[Rectangle @@@ dust4]

Редактиране: Cantor прах + квадратчета

Променени спецификации -> Ново, но подобно решение (все още не е оптимизирано).
Задайте n да бъде положително цяло число и след това изберете произволно подмножество от 1,...,n

n = 3; choice = {1, 3};
CanDChoice = c:CanD[__]/;Length[c]===n :> CanD[c[[choice]]];
splitRange = {a_, b_} :> With[{d = (b - a + 0.)/n}, 
                              CanD@@NestList[# + d &, {a, a + d}, n - 1]];

cantLevToRect[lev_]:=Rectangle@@@(Transpose/@Tuples[{lev}/.CanD->Sequence,2])

dust = NestList[# /. CanDChoice /. splitRange &, {0, 1}, 4] // Rest;

Graphics[{FaceForm[LightGray], EdgeForm[Black], 
  Table[cantLevToRect[lev], {lev, Most@dust}], 
  FaceForm[Black], cantLevToRect[Last@dust /. CanDChoice]}]

Ето графиките за

n = 7; choice = {1, 2, 4, 6, 7};
dust = NestList[# /. CanDChoice /. splitRange &, {0, 1}, 2] // Rest;

и всичко останало същото:

Харесвам рекурсивните функции, така че

cantor[size_, n_][pt_] :=
  With[{s = size/3, ct = cantor[size/3, n - 1]},
    {ct[pt], ct[pt + {2 s, 0}], ct[pt + {0, 2 s}], ct[pt + {2 s, 2 s}]}
  ]

cantor[size_, 0][pt_] := Rectangle[pt, pt + {size, size}]

drawCantor[n_] := Graphics[cantor[1, n][{0, 0}]]

drawCantor[5]

Обяснение: size е дължината на ръба на квадрата, в който се вписва наборът. pt е {x,y} координатите на долния ляв ъгъл.